Mathematische Methoden mit Mathematica

Beispiele

Manipulieren von Ausdrücken

Ausmultiplizieren

Expand[(a (x^3)+b (x^2)+c x+d)(x+f)(g (x^3)+x)]

Faktorisieren von Polynomen

Factor[(x^2)+4x+4]

Ausmultiplizieren ...

Expand[(((4+4 x+(x^2)) (x-3 (x^2)+(x^3)))/(2 x+(x^2)))]

... und Vereinfachen

Simplify[%]

Differenzieren

Die Ableitung einer Funktion lässt sich einfach schreiben:

f[x_]:=Sin[x]

f'[x]

oder so

D[f[x],x]

und bei höheren Ableitungen

f[x_]:=(x^5)-3(x^2)+10

f''[x]

oder

D[f[x],{x,3}]

Beispiel Übungsblatt 1 Aufgabe 2c)

D[(1/(1+(E^(-(x^2))))),x]

Taylorentwicklung

Reihenentwicklung der Funktion (e^x)an der Stelle x=0 bis zur 10. Ordnung:

Series[(E^x),{x,0,10}]

Series[Sin[x],{x,π/2,10}]

Beispiel Übungsblatt 4 Aufgabe 1d)

Series[(1/(Sqrt[1+x])),{x,0,5}]

Kurvendiskussion

Beispiel Übungsblatt 1 Aufgabe 1 b)

f[x_]:=x (E^(-α x))

1. und 2. Ableitung :

f'[x]

Simplify[%]

f''[x]

Simplify[%]

Grafische Darstellung für α = 1

α=1;
Plot[Tooltip[{f[x],f'[x],f''[x]}],{x,-1,8},PlotRange->{Automatic,{-1,1}}]
Clear[α]

Nullstellen

Solve[f[x]==0,x]

Bei komplizierteren Funktionen hilft eventuell nur die numerische Berechnung, dann allerdings nur für Funktionen ohne Parameter und nur einzeln mit “Starthinweis”

Solve[(x^3)-2x+Cos[x]==0,x]

FindRoot[(x^3)-2x+Cos[x],{x,1}]

Extrema lassen sich auch “Solven”

Solve[f'[x]==0,x]

f''[x/.%]

Grenzwerte für x->+/-∞

Limit[f[x],x->Infinity]

Hier wird noch eine Annahme für α benötigt :

Limit[f[x],x->Infinity,Assumptions->α>0]

Limit[f[x],x->-Infinity,Assumptions->α>0]

Integrieren

Es können unbestimmte Integrale analytisch berechnet werden

∫Log[1+x]\[DifferentialD]x

Integrate[Sin[x]Cos[x],x]

und natürlich auch bestimmte Integrale

(∫_0^∞)(E^(-(x^2)))\[DifferentialD]x

Integrate[Exp[-α t]Cos[ω t],{t,0,π/(2ω)}]

und für den Fall, dass keine analytische Lösung möglich ist, dann eben numerisch

NIntegrate[Sin[Sin[x]],{x,1,2}]

Komplexe Zahlen

Einfache Operation mit komplexen Zahlen

(Sqrt[-1])

a=4-3I

Re[a]

Im[a]

Abs[a]

Arg[a]

b=5Exp[-I ArcTan[(3/4)]]

Re[b]

Im[b]

Conjugate[a]

a Conjugate[a]

Fourier-Transformation

Fourierentwicklung der Funktion f(x)=(x^2) periodisch im Intervall [-π,π]

f[x_]:=(x^2)

Berechnung der Entwicklungskoeffizienten

an[n_]:=(1/π)Integrate[Cos[n x]f[x],{x,-π,π}]

bn[n_]:=(1/π)Integrate[Sin[n x]f[x],{x,-π,π}]

Daraus ergibt sich die Fourierreihe :

fn[x_,n_]:=an[0]/2+Sum[an[i]Cos[i x ]+bn[i]Sin[i x ],{i,1,n}]

fn[x,10]

Plot[Evaluate[{(x^2),fn[x,1],fn[x,3],fn[x,10]}],{x,-2π,2π}]

FourierSeries[(x^2),x,10]

Plot[%,{x,-2π,2π}]

Manipulate[tmp=FourierSeries[(x^2),x,n];Plot[{f[x],tmp},{x,-3/2π,3/2π}],{n,0,10,1}]

Lösung von Gewöhnlichen Differentialgleichungen

Beispiel

Allgemeine Lösung (ohne Anfangsbedingungen)

DSolve[y'[x]==Exp[x-y[x]],y,x]

Die Lösung wird als "Replacement" geliefert, das mit “/.” eingesetz werden kann

(y[x]/.%)//TraditionalForm

Beispiel Populationswachstum

Lösung mit Anfangsbedingung (Populationsgröße bei t=0 ist n0)

result=DSolve[{n'[t]==a(1-b n[t])n[t],n[0]==n0},n,t]

Simplify[n[t]/.result]

Grenzfälle

Limit[n[t]/.result,b->0]

Limit[n[t]/.result,t->Infinity,Assumptions->a>0]

Grafische Darstellung

a=0.3;b=0.01;n0=10;
Plot[{n[t]/.result,1/b,n0},{t,0,30},PlotRange->All]
Clear[a,b,n0]